'you can download IOPriorityV1.1.exe from the following
' http://sourceforge.net/projects/iopriority/

'modify path to your copy of comskip.exe
strComSkip = "L:\MePo\comskip81_056\comskip.exe"
'modify path to your copy of IOPriorityV1.1.exe
strIOpriority = "L:\MePo\comskip81_056\IOPriorityV1.1.exe"

'use chr(34) to put filename in quotes for comskip
strFileName = chr(34) & WScript.Arguments.Item(0) & chr(34)
'wscript.echo strFileName

'CPU priority selections, use LOW or BELOW_NORMAL
Const LOW = 64
Const NORMAL = 32
Const BELOW_NORMAL = 16384
Const ABOVE_NORMAL = 32768

'IO priority selections
Const IO_VERYLOW = 0
Const IO_LOW = 1
Const IO_NORMAL = 2

'select CPU and IO Priority,
CPUpriority = LOW
IOpriority = IO_VERYLOW

'don't show windows for comskip or iopriority
Const SW_HIDE = 0

strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set objStartup = objWMIService.Get("Win32_ProcessStartup")
Set objProcess = GetObject("winmgmts:root\cimv2:Win32_Process")

'set process config for comksip
Set objConfig_comskip = objStartup.SpawnInstance_
objConfig_comskip.ShowWindow = SW_HIDE 
objConfig_comskip.PriorityClass = CPUpriority

'set process config for iopriority,
Set objConfig_iopriority = objStartup.SpawnInstance_
objConfig_iopriority.ShowWindow = SW_HIDE 
objConfig_iopriority.PriorityClass = NORMAL

'start comksip
strProcessName = strComSkip & " " & strFileName
'wscript.echo strProcessName
intReturn = objProcess.Create(strProcessName, null, objConfig_comskip, intProcessID)

If intReturn <> 0 Then
    Wscript.Echo "Process could not be created." & _
        vbNewLine & "Command line: " & strProcessName & _
        vbNewLine & "Return value: " & intReturn
Else
	'start iopriority
	strProcessName = strIOpriority & " " & intProcessID & " " & IOpriority
	'wscript.echo strProcessName
	intReturn = objProcess.Create(strProcessName, null, objConfig_iopriority, intProcessID)
	
End If