Batch Datei zum starten von MePo (1 Viewer)

[noxx2]

Hallo

ich versuche mir gerade eine Batch zu basteln die MePo starten soll, klappt
aber irgendwie nicht. Evtl hat einer einen Tipp. Die Batch soll folgendes

- START
- Prüfe ob Pfad \\WHS2011\Videos verfügbar ist
- Wenn ja, Starte Programm Mediaportal
- Wenn nein, führe WOL aus
- Prüfe alle 10 Sekunden ob Pfad \\WHS2011\Videos verfügbar ist
- Wenn Server verfügbar, starte Programm Mediaportal

@echo off
if exist \\WHS2011\Videos goto Mediaportal
if not exist \\WHS2011\Videos goto WOL
 
:wol
start C:\wol.exe 112233445566 192.168.178.41
 
:Schleife
echo WARTE 10 SEKUNDEN
ping 127.0.0.1 -n 10>nul
if exist \\WHS2011\Videos goto Mediaportal
if not exist \\WHS2011\Videos goto Schleife
 
:Mediaportal
echo Server online
echo starte Mediaportal
ping 127.0.0.1 -n 3>nul
start "C:\Programme\Team Mediaportal\Mediaportal.exe"
 
:Exit
exit

 

[Makkoo]

interessiert mich auch

 

[madvario]

Von dieser Adresse das Proggi wait.exe downloaden:
http://www.petersen.de/content/contenido-4.6.4/cms/front_content.php?idart=163

Habe den Code nicht in dieses TOLLE Code-Fenster gesetzt, da es den Ping-Befehl verbogen hat.

deshalb steht der jeweilige Code zwischen Code: und Code Ende

Mach dir unter C:\ ein Ordner der z.b. Scripte heißt.

dort hinein kommt die Progs wol.exe und wait.exe, sowie deine bat

es ist einfacher alles aus einem Verzeichnis laufen zu lassen.

auf die bat machst du auf dem Desktop eine Verknüpfung


Code:

@echo off
@if exist \\WHS2011\Videos goto Mediaportal

@start wol.exe 112233445566 192.168.178.41

@SET COUNT=0

:loop

@echo Erfolglose Abfragen: %COUNT%
@wait.exe 10000
@if exist \\WHS2011\Videos goto Mediaportal

@set /a COUNT=%COUNT%+1

@if (%COUNT%) == (10) goto END

@goto loop

:Mediaportal
@echo Server online
@echo starte Mediaportal

@start "MePo" "C:\Programme\Team Mediaportal\Mediaportal.exe"

exit

:END
@echo Server starten fehlgeschlagen
@echo.
@echo.
@echo.
@pause
@Exit

Code ende


Da ich den Befehl if exist aber nicht so mag, läuft das bei mir über Ping, aber es wird nur eine für eine Antwort angefragt und es wird nur 5ms auf Antwort gewartet (Einige Router senden Antworten der Nichterreichbarkeit mit dem Absender des angeforderten, wodurch der Ping fälschlicherweise positiv ausgewertet wird.). Und das geht auch schneller als mit if exist :

Code:

@echo off

@ping -n 1 -w 5 WHS2011 && goto Mediaportal


@start C:\wol.exe 112233445566 192.168.178.41

@SET COUNT=0

:loop

@echo Erfolglose Abfragen: %COUNT%
@wait.exe 10000
@ping -n 1 -w 5 WHS2011 && goto Mediaportal

@set /a COUNT=%COUNT%+1

@if (%COUNT%) == (10) goto END

@goto loop

:Mediaportal
@echo Server online
@echo starte Mediaportal

@start "MePo" "C:\Programme\Team Mediaportal\Mediaportal.exe"

exit

:END
@echo Server starten fehlgeschlagen
@echo.
@echo.
@echo.
@pause
@Exit

Code ende


Zusätzlich könntest du über das Script auch noch die freigegebenen Ordner als Netzlaufwerke einbinden.

Das baust du dann vor dem Start "MePo" ein, also etwa so:

Code:

@echo Server online

@net use z: \\WHS2011\Videos

@echo starte Mediaportal

@start "MePo" "C:\Programme\Team Mediaportal\Mediaportal.exe"

Code ende


Falls noch Fragen, bitte melden

 

[noxx2]

Danke, aber funktioniert nicht ganz. habs mal mit einer IP probiert die es nicht gibt im Netzwerk.
1x scheint er einen WOL zu senden, aber er wartet nicht bis die IP verfügbar ist, sondern
startet MePo einfach. Habe dein 2tes Script probiert.[DOUBLEPOST=1352641772][/DOUBLEPOST]geht doch, hatte in :loop die IP vom Server vergessen, danke

 

[eisblock]

hoi, thx für das schöne Skript, daß hat mein altes nun ersetzt :=)
Da ich alle Thumbs auf einem Netzlaufwerk habe und in Mediaportal, ohne vorher das Netzlaufwerk aufzurufen, keine Thumbs anzeigt werden. Habe ich noch folgede Zeile nach @net use ... eingefügt
@start /min explorer Z:

gruss eisblock